runelite/runelite-client/build.gradle

import org.apache.tools.ant.filters.ReplaceTokens
import java.text.SimpleDateFormat

plugins {
    id 'com.github.johnrengelman.shadow' version '5.1.0'
    id 'java'
}

description = 'RuneLite Client'

dependencies {
    annotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombok

    compileOnly group: 'javax.annotation', name: 'javax.annotation-api', version: javax
    compileOnly group: 'net.runelite', name: 'orange-extensions', version: orangeExtensions
    compileOnly group: 'org.projectlombok', name: 'lombok', version: lombok

    implementation group: 'ch.qos.logback', name: 'logback-classic', version: logback
    implementation group: 'com.google.code.gson', name: 'gson', version: gson
    implementation group: 'com.google.guava', name: 'guava', version: guava
    implementation group: 'com.google.inject', name: 'guice', version: guice, classifier: 'no_aop'
    implementation group: 'com.h2database', name: 'h2', version: h2
    implementation group: 'com.jakewharton.rxrelay2', name: 'rxrelay', version: rxrelay
    implementation group: 'com.squareup.okhttp3', name: 'okhttp', version: okhttp3
    implementation group: 'io.reactivex.rxjava2', name: 'rxjava', version: rxjava
    implementation group: 'net.java.dev.jna', name: 'jna', version: jna
    implementation group: 'net.java.dev.jna', name: 'jna-platform', version: jna
    implementation group: 'net.runelite', name: 'discord', version: discord
    implementation group: 'net.runelite.pushingpixels', name: 'substance', version: substance
    implementation group: 'net.sf.jopt-simple', name: 'jopt-simple', version: jopt
    implementation group: 'org.apache.commons', name: 'commons-text', version: apacheCommonsText
    implementation group: 'org.apache.httpcomponents', name: 'httpcore', version: httpcore
    implementation group: 'org.apache.httpcomponents', name: 'httpmime', version: httpmime
    implementation group: 'org.codehaus.plexus', name: 'plexus-utils', version: plexus
    implementation group: 'org.javassist', name: 'javassist', version: javassist
    implementation group: 'org.jetbrains', name: 'annotations', version: annotations
    implementation group: 'org.jogamp.gluegen', name: 'gluegen-rt', version: jogamp
    implementation group: 'org.jogamp.jogl', name: 'jogl-all', version: jogamp
    implementation group: 'org.jooq', name: 'jooq', version: jooq
    implementation group: 'org.jooq', name: 'jooq-codegen', version: jooq
    implementation group: 'org.jooq', name: 'jooq-meta', version: jooq
    implementation group: 'org.ow2.asm', name: 'asm-tree', version: asm
    implementation group: 'org.slf4j', name: 'slf4j-api', version: slf4j
    implementation group: 'org.xeustechnologies', name: 'jcl-core', version: jclCore
    implementation project(':http-api')
    implementation project(':runelite-api')
    implementation(group: 'io.sigpipe', name: 'jbsdiff', version: jbsdiff) {
        exclude(module: 'xz')
    }
    implementation group: 'com.github.joonasvali.naturalmouse', name: 'naturalmouse', version: '2.0.2'
    runtime group: 'net.runelite.pushingpixels', name: 'trident', version: trident
    runtime group: 'org.jogamp.gluegen', name: 'gluegen-rt', version: jogamp, classifier: 'natives-linux-amd64'
    runtime group: 'org.jogamp.gluegen', name: 'gluegen-rt', version: jogamp, classifier: 'natives-linux-i586'
    runtime group: 'org.jogamp.gluegen', name: 'gluegen-rt', version: jogamp, classifier: 'natives-windows-amd64'
    runtime group: 'org.jogamp.gluegen', name: 'gluegen-rt', version: jogamp, classifier: 'natives-windows-i586'
    runtime group: 'org.jogamp.jogl', name: 'jogl-all', version: jogamp, classifier: 'natives-linux-amd64'
    runtime group: 'org.jogamp.jogl', name: 'jogl-all', version: jogamp, classifier: 'natives-linux-i586'
    runtime group: 'org.jogamp.jogl', name: 'jogl-all', version: jogamp, classifier: 'natives-windows-amd64'
    runtime group: 'org.jogamp.jogl', name: 'jogl-all', version: jogamp, classifier: 'natives-windows-i586'
    runtime project(':injected-client')
    runtime project(':runescape-api')

    testAnnotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombok

    testCompileOnly group: 'org.projectlombok', name: 'lombok', version: lombok

    testImplementation group: 'com.google.inject.extensions', name: 'guice-grapher', version: guice
    testImplementation group: 'com.google.inject.extensions', name: 'guice-testlib', version: guice
    testImplementation group: 'junit', name: 'junit', version: junit
    testImplementation group: 'org.hamcrest', name: 'hamcrest-library', version: hamcrest
    testImplementation group: 'org.mockito', name: 'mockito-core', version: mockito
    testImplementation group: 'org.mockito', name: 'mockito-inline', version: mockito
    testImplementation group: 'org.slf4j', name: 'slf4j-api', version: slf4j
}

static def getDate() {
    return new SimpleDateFormat("MM-dd-yyyy", Locale.forLanguageTag("en-US")).format(new Date())
}

def buildDate = getDate()

processResources {
    from file("src/main/resources/open.osrs.properties"), {
        filter(ReplaceTokens, tokens: [
                "project.version": project.version,
                "rs.version": rsversion.toString(),
                "open.osrs.version": plusVersion.toString(),
                "open.osrs.builddate": buildDate.toString(),
                "launcher.version": launcherVersion.toString()
        ])
    }
}

tasks.withType(AbstractArchiveTask) {
    preserveFileTimestamps = false
    reproducibleFileOrder = true
}

jar {
    manifest {
        attributes 'Main-Class': 'net.runelite.client.RuneLite'
    }
}

shadowJar {
    archiveClassifier.set("shaded")

    exclude("net/runelite/injector/**")
}

task dependencyReportFile(type: DependencyReportTask) {
    outputFile = file('dependencies.txt')
    Set configs = [project.configurations.runtimeClasspath]
    setConfigurations(configs)
}

tasks.build.dependsOn tasks.shadowJar
tasks.shadowJar.dependsOn tasks.dependencyReportFile