repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

description = 'RuneLite Wiki scraper'

dependencies {
    api project(':cache')
    api project(':runelite-api')

    annotationProcessor group: 'org.projectlombok', name: 'lombok', version: lombok

    compileOnly group: 'org.projectlombok', name: 'lombok', version: lombok

    implementation group: 'com.google.code.gson', name: 'gson', version: gson
    implementation group: 'com.google.guava', name: 'guava', version: guava
    implementation group: 'com.github.petitparser', name: 'java-petitparser', version: '2.2.0'
    implementation group: 'com.squareup.okhttp3', name: 'okhttp', version: okhttp3
    implementation group: 'org.slf4j', name: 'slf4j-api', version: slf4j
    implementation group: 'org.slf4j', name: 'slf4j-simple', version: slf4j

    testImplementation group: 'org.junit.jupiter', name: 'junit-jupiter-api', version: jupiter
}

task npcStatsScrape {
    doLast {
        def path = sourceSets.main.runtimeClasspath
        def loader = new URLClassLoader(path.collect { f -> f.toURI().toURL() } as URL[])
        def scrape = loader.loadClass('net.runelite.data.App')
        scrape.npcStats(rootProject.file("./runelite-client/src/main/resources/"));

        loader.close()
    }
}

task itemStatsScrape {
    doLast {
        def path = sourceSets.main.runtimeClasspath
        def loader = new URLClassLoader(path.collect { f -> f.toURI().toURL() } as URL[])
        def scrape = loader.loadClass('net.runelite.data.App')
        scrape.itemStats(rootProject.file("./runelite-client/src/main/resources/"));

        loader.close()
    }
}

task itemLimitsScrape {
    doLast {
        def path = sourceSets.main.runtimeClasspath
        def loader = new URLClassLoader(path.collect { f -> f.toURI().toURL() } as URL[])
        def scrape = loader.loadClass('net.runelite.data.App')
        scrape.itemLimits(rootProject.file("./runelite-client/src/main/resources/net/runelite/client/plugins/grandexchange/"));

        loader.close()
    }
}