/*
 * Copyright (c) 2021, ThatGamerBlue <thatgamerblue@gmail.com>
 * Copyright (c) 2022, Owain van Brakel <https://github.com/Owain94>
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions are met:
 *
 * 1. Redistributions of source code must retain the above copyright notice, this
 *    list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright notice,
 *    this list of conditions and the following disclaimer in the documentation
 *    and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS" AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
 * WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
 * DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR
 * ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
 * (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
 * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
 * ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
 * SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */

import java.io.File
apply<FernflowerPlugin>()

description = "Injected Client"

plugins {
    id("com.openosrs.injector")
}

val vanillaDep by configurations.creating
val rsapiDep by configurations.creating
val rsclientDep by configurations.creating
val mixinsDep by configurations.creating
val combined by configurations.creating {
    extendsFrom(rsapiDep, rsclientDep, mixinsDep, vanillaDep)
    isCanBeResolved = true
    isCanBeConsumed = false
}

configurations {
    all {
        isTransitive = false
    }
}

val vanillaJarProp: String? = (findProperty("vanillaJar") as String?) ?: System.getenv("VANILLA_JAR")
val vanillaJarFile: File? = vanillaJarProp?.let { file(it) }?.takeIf { it.exists() }

dependencies {
    if (vanillaJarFile != null) {
        vanillaDep(files(vanillaJarFile))
    } else {
        // Fallback to local project jar to avoid private repo dependency
        vanillaDep(project(":runescape-client"))
    }
    rsapiDep(project(":runescape-api"))
    rsclientDep(project(":runescape-client"))
    mixinsDep(project(":runelite-mixins"))
}

injector {
    mixins.set(mixinsDep.singleFile)
    rsapi.set(rsapiDep.singleFile)
    rsclient.set(rsclientDep.singleFile)
    vanilla.set(vanillaDep.singleFile)
    // Temporarily skip fragile steps for obfuscated jars without parameter metadata
    skip.set("MixinInjector RSApiInjector")
}

// keep the sourcesets etc but remove useless tasks
tasks {
    inject {
        dependsOn(combined)
    }
    classes {
        enabled = false
    }
    compileJava {
        enabled = false
    }
    jar {
        enabled = false
    }
    processResources {
        enabled = false
    }
}